Tugas 8

Karakteristik I-V dan Frekuensi Tinggi MOSFET

Pertama kali kita masukkan doping profile yang kita miliki ke dalam file mosfet.gr0. Dalam file ini nilai-nilai parameternya didapatkan dari tahap desain sebelumnya

Title File : mosfet.gr0

$ Tugas EL-312 (Devais Mikroelektronika)

$ Grid of the structure and doping distribution

$ Define rectangular grid

mesh rectangular nx=25 ny=25 diag.flip smooth=1

x.mesh n=1 l=0 r=1

x.mesh n=25 l=2.5 r=1

y.mesh n=1 l=-0.1 r=1

y.mesh n=3 l=0 r=1

y.mesh n=14 l=0.7 r=1.05

y.mesh n=25 l=2.5 r=1.2

$ Regions

region num=1 y.max=0 oxide

region num=2 y.min=0 silicon

$ Electrodes

$ #1-GATE #2-SUBSTRATE #3-SOURCE #4-DRAIN

electrode num=1 x.min=0.520 length=1.460

electrode num=2 substrate

electrode num=3 source length=0.417 y.min=0 y.max=0

electrode num=4 drain length=0.417 y.min=0 y.max=0

$ Doping and Fixed Charge

doping reg=2 gauss conc=9.7947e15 characteristic=0.10

+ acceptor peak=0.0 outf=doping.mos

doping reg=2 gauss conc=1.e20 characteristic=0.10

+ donor peak=0.0 x.r=0.6 ratio=0.75

doping reg=2 gauss conc=1.e20 characteristic=0.10

+ donor peak=0.0 x.l=2.0 ratio=0.75

doping reg=2 uniform conc=9.7947e15 acceptor

$ Regrid on Doping

plot.2d grid no.top boundary no.fill pa

regrid doping log reg=2 ratio=4 smooth.k=1 outf=mesh1.mos dopfile=doping.mos

regrid doping log reg=2 ratio=4 smooth.k=1 outf=mesh2.mos dopfile=doping.mos

$ Contact

contact num=1 n.polysilicon

symbolic gummel carriers=0

solve initial

regrid potential ratio=0.2 region=2 smooth.k=1 outf=mesh3.mos dopfile=doping.mos

$ Plotting

plot.2d grid no.top boundary no.fill pa

plot.1d log abs doping x.s=0 y.s=0 x.e=0 y.e=2.5 points pa

plot.1d log abs doping x.s=0 y.s=0 x.e=2.5 y.e=0 line.type=2 pa

plot.1d log abs doping x.s=1.2 y.s=0 x.e=1.2 y.e=1.5 line.type=2 pa

end

Output plot:

 

Title File : mosfet.gr1

$ Tugas EL-312 (Devais Mikroelektronika)

$ Full set of Id / Vd for gate voltages = 1, 2, 3 and 4 V

mesh inf=mesh3.mos

contact num=1 n.polysilicon

models print temp=300 conmob fldmob bgn fermi incomplete

+ tfldmb2 OX.L=0.6 OX.R=2.

interf qf=3e10

symb newton carrier=1 electrons

method xnorm autonr itlimit=30 trap atrap=.5 p.tol=1.e-4 c.tol=1.e-4

solve initial

solve previous v4=0.005

solve project vstep=0.25 nstep=3 elect=1

solve project v1=1.0 outf=g111.mos

solve project vstep=0.25 nstep=3 elect=1

solve project v1=2.0 outf=g211.mos

solve project vstep=0.25 nstep=3 elect=1

solve project v1=3.0 outf=g311.mos

solve project vstep=0.25 nstep=3 elect=1

solve project v1=4.0 outf=g411.mos

$ Calculate drain characteristics for each gate voltage

load inf=g111.mos

log outf=d111.mos

solve vstep=0.1 nstep=9 elect=4 previous

solve previous v4=1.0 vstep=0.1 nstep=40 elect=4

load inf=g211.mos

log outf=d211.mos

solve vstep=0.1 nstep=9 elect=4 previous

solve previous v4=1.0 vstep=0.1 nstep=40 elect=4

load inf=g311.mos

log outf=d311.mos

solve vstep=0.1 nstep=9 elect=4 previous

solve previous v4=1.0 vstep=0.1 nstep=40 elect=4

load inf=g411.mos

log outf=d411.mos

solve vstep=0.1 nstep=9 elect=4 previous

solve previous v4=1.0 vstep=0.1 nstep=40 elect=4

end

Title File : mosfet.gr2

$ Tugas EL-312 (Devais Mikroelektronika)

$ Substrate current vs gate voltage for drain voltages of 4.0 and 5.0V

mesh inf=mesh3.mos

contact num=1 n.polysilicon

models print temp=300 conmob fldmob bgn fermi incomplete

+ tfldmb2 OX.L=0.6 OX.R=2.

impact

interf qf=3e10

$ Calculate initial solution

symb carriers=0

method iccg damped itlimit=30

solve init

$ Calculate solution at gate voltage Vg=0.3 V and two drain voltages

solve v1=0.3 v4=4.0 local outf=sb4.mos

solve v1=0.3 v4=5.0 local outf=sb5.mos

symb newton carrier=2

method xnorm autonr itlimit=16 trap atrap=.5 p.tol=1.e-3 c.tol=1.e-2

$ Calculate substrate current versus gate voltage at Vd = 4.0 V

load inf=sb4.mos

log outf=substr4.mos

solve prev v1=0.4 vstep=0.1 nstep=6 electr=1

solve prev vstep=0.5 nstep=6 electr=1

$ Calculate substrate current versus gate voltage at Vd = 5.0 V

load inf=sb5.mos

log outf=substr5.mos

solve prev v1=0.4 vstep=0.1 nstep=6 electr=1

solve prev vstep=0.5 nstep=6 electr=1

end

Title File : mosfet.gr3

$ Tugas EL-312 (Devais Mikroelektronika)

$ AC simulation

mesh inf=mesh3.mos

contact num=1 aluminum

interf qf=3.e10

symb newton carr=2

method xnorm autonr

models print temp=300 fldmob srh auger conmob tfldmb2 ox.l=0.0 ox.r=2.0

solve init

log acfile=ac.mos

solve previous v1=-1.00 ac freq=1.e6 term=12

solve previous v1=-0.75 vstep=0.5 nstep=25 elect=1 ac freq=1.e6 term=12

end

Title File : mosfet.gr4

$ Tugas EL-312 (Devais Mikroelektronika)

$ AC simulation

mesh inf=mesh3.mos

contact num=1 aluminum

models print temp=300 conmob fldmob bgn fermi incomplete

+ tfldmb2 ox.l=0.6 ox.r=2 ox.b=0

interf qf=3.e10

symb newton carr=2

method xnorm autonr itlimit=20 trap atrap=.5 p.tol=1.e-4 c.tol=1.e-4

load inf=g411.mos

symb newton carr=2

log acfile=ac1.mos

solve ac freq=1 fstep=4 mult.f nfstep=15 vss=0.01

+ max.inner=250 s.omega=0.30 terminal=2

end

Title File : mosfet.iv1

$ Tugas EL-312 (Devais Mikroelektronika)

$ Plot substrate current vs gate voltage

mesh inf=mesh3.mos

plot.1d inf=substr5.mos x.ax=v1 y.ax=i2 abs

+ x.label=Vgate y.label=Isub min.value=-13 x.max=6 log points pa

+ title="Isubstrate vs Vgate"

plot.1d inf=substr4.mos x.ax=v1 y.ax=i2 abs log points unch pa

end

Output plot:

 

Title File : mosfet.oc1

$ Tugas EL-312 (Devais Mikroelektronika)

$ Plot karakteristik output

mesh inf=mesh3.mos

plot.1d inf=d411.mos x.ax=v4 y.ax=i4 abs x.label=Vds y.label=Ids pa

+ title="Fitting N-MOSFET" max=3.9e-4

+ subtitle="Karakteristik output"

plot.1d inf=d311.mos x.ax=v4 y.ax=i4 abs unch pa

plot.1d inf=d211.mos x.ax=v4 y.ax=i4 abs unch pa

plot.1d inf=d111.mos x.ax=v4 y.ax=i4 abs unch pa

fit mos fit.type=2 bulk=2 drain=4 gate=1 line1.type=4 line2.type=5

end

Output plot:

 

 

Title File : mosfet.cv1

$ Tugas EL-312 (Devais Mikroelektronika)

$ AC Simulation

mesh inf=mesh3.mos

plot.1d inf=ac.mos x.ax=v1 y.ax=c12 points

+ title="Plot kapasitansi vs Vgate"

+ y.label="Cgate-substrate" x.label="Vgate" pa

end

Output plot:

Title File : mosfet.gf1

$ Tugas EL-312 (Devais Mikroelektronika)

$ Plot gain terhadap frekuensi

mesh inf=mesh3.mos

plot.1d inf=ac1.mos x.ax=freq y.ax=i4/v1 abs

+ title="Kurva karakteristik" subtitle="frekuensi tinggi"

+ y.label="Penguatan" x.label="Frekuensi" pa

end

Output plot: